home *** CD-ROM | disk | FTP | other *** search
/ The Game Master (2nd Edition) / Game Master 2nd Edition Advantage Plus Dist. Inc. 1992.ISO / files / hobbbies / garden / garden.bas
Encoding:
BASIC Source File  |  1986-05-17  |  8.0 KB  |  177 lines
  1. 10 REM
  2. 20 REM   GARDEN PLANNING PROGRAM
  3. 30 REM
  4. 40 REM    written by Ted Batutis 
  5. 50 REM            for  The Good Earth SIG
  6. 60 REM             on  CompuServe Information Service
  7. 70 REM
  8. 80 REM    Copyright 1982 by Ted Batutis 
  9. 90 REM  ALL COMMERCIAL RIGHTS RESERVED
  10. 100 REM      Feel free to distribute this program
  11. 110 GOSUB 1520 
  12. 120 CLS
  13. 130 PRINT"***************************"
  14. 140 PRINT"  Garden Planning Program  "
  15. 150 PRINT"***************************"
  16. 160 PRINT:PRINT:PRINT:PRINT
  17. 170 PRINT"Do you want directions";
  18. 180 INPUT A$
  19. 190 IF A$="Y" OR A$="y" OR A$="YES" OR A$="yes" THEN GOSUB 710
  20. 200 REM start of program
  21. 210 CLS
  22. 220 PRINT"Data for the following crops is "
  23. 230 PRINT"available:"
  24. 240 PRINT" 1 Snap beans 13 Onions"
  25. 250 PRINT" 2 Pole beans 14 Peas"
  26. 260 PRINT" 3 Lima beans 15 Peppers"
  27. 270 PRINT" 4 Beets      16 Potatoes"
  28. 280 PRINT" 5 Broccoli   17 Pumpkins"
  29. 290 PRINT" 6 Cabbage    18 Radishes"
  30. 300 PRINT" 7 Carrots    19 Spinach"
  31. 310 PRINT" 8 Corn       20 Summer squash"
  32. 320 PRINT" 9 Cucumbers  21 Winter squash"
  33. 330 PRINT"10 Eggplant   22 Tomatoes"
  34. 340 PRINT"11 Lettuce    23 Watermelon"
  35. 350 PRINT"12 Muskmelons 24 >>EXIT PROGRAM"
  36. 360 PRINT"Which number do you want";
  37. 370 INPUT A:A=INT(A):IF A=24 THEN PRINT" Good Gardening!":PRINT:END
  38. 380 IF A<1 OR A>24 THEN PRINT"Invalid choice":GOTO 260
  39. 390 CLS:PRINT:PRINT
  40. 400 PRINT"You have chosen ";C$(A)
  41. 410 PRINT"How many feet of row might you"
  42. 420 PRINT"plant";
  43. 430 INPUT F
  44. 440 CLS
  45. 450 PRINT"Here is the information for "
  46. 460 PRINT F;" feet of ";C$(A)
  47. 470 F=F/10
  48. 480 PRINT "Approximate yield is ";
  49. 490 Y2=INT(Y(A)*F+.5):PRINT Y2;:PRINT " ";U$(A)
  50. 500 PRINT "at a spacing of ";S$(A);" inches "
  51. 510 PRINT "between plants."
  52. 520 IF A=16 THEN PRINT"You will need ";INT((O(16)*F)/16):PRINT" lbs. of potato seed pieces.":PRINT:GOTO 640
  53. 530 O2=O(A)*F
  54. 540 IF O2<.015625 THEN O2$="less than 1/64":GOTO 630
  55. 550 IF O2>=.015625 AND O2<.03125 THEN O2$="between 1/64 and 1/32":GOTO 630
  56. 560 IF O2>=.03125 AND O2<.0625 THEN O2$="between 1/32 and 1/16":GOTO 630
  57. 570 IF O2>=.0625 AND O2<.125 THEN O2$="between 1/16 and 1/8":GOTO 630
  58. 580 IF O2>=.125 AND O2<.25 THEN O2$="between 1/8 and 1/4":GOTO 630
  59. 590 IF O2>=.25 AND O2<.5 THEN O2$="between 1/4 AND 1/2":GOTO 630
  60. 600 IF O2>=.5 AND O2<1.01 THEN O2$="between 1/2 AND 1":GOTO 630
  61. 610 O2=INT(O2+.5):PRINT"You will need about ";O2;" ounces "
  62. 620 IF A=13 THEN PRINT "of onion sets.":PRINT:GOTO 640 ELSE PRINT "of seed.":PRINT:GOTO 640
  63. 630 PRINT"You will need ";O2$:PRINT" ounces of";:IF A=13 THEN PRINT" onion sets." ELSE PRINT " seeds."
  64. 640 PRINT "Fertilizer rates :"
  65. 650 PRINT "::Manure (approximate):";
  66. 660 F3=INT(F1(A)*F+.5):PRINT F3;:PRINT "lbs."
  67. 670 PRINT "::Chemical (10-10-10):";
  68. 680 F4=INT((F2(A)*F)*10+.5):F4=F4/10:PRINT F4;:PRINT "cups."
  69. 690 PRINT"Hit return --->";:INPUT A$:GOTO 210
  70. 700 END
  71. 710 REM INSTRUCTIONS
  72. 720 CLS
  73. 730 PRINT" * * * * * * * * * * * * * * * *"
  74. 740 PRINT"This program is designed to help"
  75. 750 PRINT"you in planning and planting "
  76. 760 PRINT"your garden.  You will be shown"
  77. 770 PRINT"a list of crops.  Pick one of "
  78. 780 PRINT"of them by number.  You will "
  79. 790 PRINT"then be asked how many feet of"
  80. 800 PRINT"row that you might be planning"
  81. 810 PRINT"to plant of that crop.  The "
  82. 820 PRINT"program will then tell you how"
  83. 830 PRINT"much yield you can expect, how"
  84. 840 PRINT"much seed you should buy and"
  85. 850 PRINT"about how much fertilizer to use."
  86. 860 PRINT"Fertilizer rates will "
  87. 870 PRINT "Hit return--->";
  88. 880 INPUT A$
  89. 890 CLS
  90. 900 PRINT"be given in terms of pounds"
  91. 910 PRINT"of manure per row and cups of"
  92. 920 PRINT"of 10-10-10 (a common garden "
  93. 930 PRINT"chemical fertilizer mixture)."
  94. 940 PRINT"One word of warning:"
  95. 950 PRINT"Different soils need different"
  96. 960 PRINT"amounts of fertilizer to give "
  97. 970 PRINT"the best yield.  For instance,"
  98. 980 PRINT"sandy soils require more fertil-"
  99. 990 PRINT"izer than clayey soils with "
  100. 1000 PRINT"silty soils in between.  The"
  101. 1010 PRINT"rates given will be for the av-"
  102. 1020 PRINT"erage type of soil.  You should"
  103. 1030 PRINT"judge on your own how much more "
  104. 1040 PRINT"Hit return-->";
  105. 1050 INPUT A$
  106. 1060 CLS
  107. 1070 PRINT"or less  you should use in your"
  108. 1080 PRINT"own garden.  "
  109. 1090 PRINT"Also, the fertilizer value of "
  110. 1100 PRINT"manure varies widely depending"
  111. 1110 PRINT"on source and how it has been"
  112. 1120 PRINT"handled.  "
  113. 1130 PRINT:PRINT"Experience is the very "
  114. 1140 PRINT"best teacher in these regards."
  115. 1150 PRINT:PRINT"Good gardening!":PRINT
  116. 1160 PRINT" Ted Batutis and Dave Peyton":PRINT
  117. 1170 PRINT"Hit return--->";
  118. 1180 INPUT A$
  119. 1190 RETURN
  120. 1200 REM data section
  121. 1210 REM   If you would like to customize this program
  122. 1220 REM   by adding your favorite crops or changing the
  123. 1230 REM   fertilizer rates, etc., this is where you do it.
  124. 1240 REM The first set of data is the crop names.  Note that they
  125. 1250 REM  are in the same order as the crop menu.  If you add more
  126. 1260 REM  crops, you'll have to re-dimension the appropriate variables,
  127. 1270 REM  change the menu section and initialization section.
  128. 1280 DATA "SNAP BEANS","POLE BEANS","LIMA BEANS","BEETS","BROCCOLI","CABBAGE","CARROTS"
  129. 1290 DATA "CORN","CUCUMBERS","EGGPLANT","LETTUCE","MUSKMELONS","ONIONS","PEAS","PEPPERS"
  130. 1300 DATA "POTATOES","PUMPKINS","RADISHES","SPINACH","SUMMER SQUASH","WINTER SQUASH"
  131. 1310 DATA "TOMATOES","WATERMELONS"
  132. 1320 REM  Next comes the data for wt of seed required per 10 feet of row in oz.
  133. 1330 REM   the assumption is that you plant 3X recommended density then thin
  134. 1340 DATA 1.6,1.0,4,.16,.02,.006,.0072,.264,.027,.006,.005,.01286,10,4
  135. 1350 DATA .006,35,.0343,.144,.048,.018,.27,.005,.06
  136. 1360 REM  the next set of data statements refers to the spacing for each of
  137. 1370 REM    the above crops in inches.
  138. 1380 DATA "2-4","4-6","4-6","2-3","18-24","12-18","1-3","10-12","12-15","18-24"
  139. 1390 DATA "12","36-48","2-4"
  140. 1400 DATA "2-3","18-24","8-10","60-90","1","2-4","18-24","36-48","18-24","60-90"
  141. 1410 REM   next are the data for yield per 10 foot of row
  142. 1420 DATA 12,15,4,15,10,15,10,12,12,10,9,11,10,1.5,6,25,15,3.5,4.5,15,15,25,8
  143. 1430 REM  Next are the data for the units of the above
  144. 1440 DATA "LBS.","LBS.","LBS.","LBS.","LBS.","LBS.","LBS.","EARS","LBS.","LBS.","HEADS","FRUITS"
  145. 1450 DATA "LBS.","PINTS","LBS.","LBS.","LBS.","LBS.","LBS.","LBS.","LBS.","LBS.","FRUIT"
  146. 1460 REM  Here are the fertilizer rates for a ten foot row in terms of manure
  147. 1470 REM   in lbs.
  148. 1480 DATA 04,04,04,15,12,12,10,15,10,10,10,10,15,05,12,20,10,10,15,10,10,10,10
  149. 1490 REM  Here are the fertilizer rates for a 10-10-10 chemical fertilizer
  150. 1500 REM     formulation (for a ten foot row as well) in cups
  151. 1510 DATA .25,.25,.25,.5,.5,.5,.5,.5,.5,.5,.5,.5,.5,.25,.5,.5,.5,.5,.3,.5,.5,.5,.5
  152. 1520 REM  INITIALIZATION
  153. 1530 DIM C$(23),O(23),S$(23),Y(23),U$(23),F1(23),F2(23)
  154. 1540 REM  The variables are CROP, OUNCES,SPACING,YIELD, UNITS, FERTILIZER RATE
  155. 1550 REM    for MANURE (1) and 10-15-10 (2)
  156. 1560 FOR I=1 TO 23
  157. 1570 READ C$(I)
  158. 1580 NEXT I
  159. 1590 FOR I=1 TO 23
  160. 1600 READ O(I)
  161. 1610 NEXT I
  162. 1620 FOR I=1 TO 23
  163. 1630 READ S$(I)
  164. 1640 NEXT I
  165. 1650 FOR I=1 TO 23
  166. 1660 READ Y(I)
  167. 1670 NEXT I
  168. 1680 FOR I=1 TO 23
  169. 1690 READ U$(I)
  170. 1700 NEXT I
  171. 1710 FOR I=1 TO 23
  172. 1720 READ F1(I)
  173. 1730 NEXT I
  174. 1740 FOR I=1 TO 23
  175. 1750 READ F2(I)
  176. 1760 NEXT I
  177. 1770 RETURN
  178.